Pular para o conteúdo principal

db_num_fields

descrição​

A função retorna o número de campos (colunas) do resultado obtido com db_query.

NomeDescrição
DBResult:dbresultResultado retornado por db_query.

retorno​

Número de campos no resultado.

exemplo​

// examples.inc

static FindFieldIndexByName(DBResult:dbResultSet, const fieldName[])
{
    new ret = -1;
    new field_count = db_num_fields(dbResultSet);
    new current_field_name[32];

    for (new field_index = 0; field_index < field_count; field_index++)
    {
        if (db_field_name(dbResultSet, field_index, current_field_name, sizeof current_field_name))
        {
            if (!strcmp(fieldName, current_field_name))
            {
                ret = field_index;
                break;
            }
        }
    }

    return ret;
}

Float:Examples_CalculateSum(DB:dbConnectionHandle)
{
    new Float:ret;
    new DBResult:db_result_set = db_query("SELECT `value` FROM `examples`");

    if (db_result_set)
    {
        new target_field_index = FindFieldIndexByName(db_result_set, "value");

        if (target_field_index >= 0)
        {
            do
            {
                ret += db_get_field_float(db_result_set, target_field_index);
            }
            while (db_next_row(db_result_set));
        }

        db_free_result(db_result_set);
    }

    return ret;
}
// mode.pwn

#include <examples>

static DB:gDBConnectionHandle;

public OnGameModeInit()
{
    gDBConnectionHandle = db_open("example.db");

    if (gDBConnectionHandle)
    {
        print("Conexão com banco \"example.db\" criada com sucesso.");
        printf("Soma calculada: %f", Examples_CalculateSum(gDBConnectionHandle));
    }
    else
    {
        print("Falha ao abrir conexão com banco \"example.db\".");
    }

    return 1;
}

public OnGameModeExit()
{
    if (db_close(gDBConnectionHandle))
    {
        gDBConnectionHandle = DB:0;
    }
    return 1;
}

notas​

funções relacionadas​